10 techniques for building a Google Sheets dashboard

You’re probably familiar with Google Sheets and maybe you use it to organize and analyze your data. But did you know you can build a dynamic Google Sheets dashboard to really understand your data?

With a handful of powerful techniques, you can add some pizzazz and dynamism to the presentation of your data. Here are ten tricks to try next time you’re building a Google Sheets dashboard.

Google Sheets dashboard for digital marketing
Google Sheets dashboard for digital marketing, covered in my online course

Contents

  1. Collect user inputs through a Google Form into a dashboard
  2. Retrieve data with LOOKUP formulas
  3. Apply logic with conditional formulas
  4. Automate your dates
  5. Add interactivity with data validation
  6. Chart your data
  7. Show trends with sparklines
  8. Apply conditional formatting to show changes
  9. Format like a pro!
  10. Share and publish your dashboard for the world to see

1. Collect user inputs through a Google Form into a Google Sheets dashboard

Google Forms are a quick and easy way to collect data. The responses are collected in a Google Sheet which we can then use to power a dashboard. For example, you could run a survey on customer satisfaction, or status reports from your operations team members, and then turn this data into a one page visual summary, giving you instant insight into your data. Let’s run through a super quick and simple example:

Step 1: Create a form

Create a Google form in Google Drive (detailed instructions here) by navigating to:

Drive > New > More > Google Forms

Step 2: Setup the form

Next, setup your Google Form by giving it a name and adding any questions that you have. In this example, I’ve created a form with one multiple choice question which asks a user which color they prefer (from red, blue or green):

Google Form example

Step 3: Create the Google Sheets dashboard

View your responses and setup the Google Sheets dashboard. You’ll need to submit the form at least once, so that you have some data in your responses which you can use. I then added a new tab and created a new table (a staging table), which uses a countif formula (see section 3 on conditional formulas below) to tally up the votes for each color and show this count in the staging table. Then I added a bar chart and pie chart (see section 6 on charts below) running off this staging table to display the counts visually. These charts will update whenever new votes are submitted.

Google Forms dashboard

Add your own choice through the form here: Color Choice Form

View the dashboard here: Google Form Dashboard Example

Build Business Dashboards With Google Sheets and Data Studio

Digital marketing dashboard in Google Sheets
Learn how to build beautiful, interactive dashboards in my online course.
9+ hours of video content, lifetime access and copies of all the finished dashboard templates.
Learn more

2. Retrieve data with LOOKUP formulas

Mastering lookup formulas is a key technique for many data projects in Google Sheets (and Excel). It’s at the heart of the Google Sheets dashboard shown at the start of this post and such a useful technique in it’s own right that I’d recommend investing time to practice this technique. There are several methods at your disposal:

VLOOKUP is a vertical lookup formula which searches the first column of a range, and when it finds the first instance of the result (if there is one), it returns the value in that row from the column of the range that you specify with the index value, e.g.:

=VLOOKUP(F1,A1:D20,4,FALSE)

This formula takes the search term in cell F1, for example a string “Channel A”, and looks for it in column A. At the first match, if it exists, (e.g. imagine cell A10 contains “Channel A”) it returns the value corresponding to column 4 of that same row (in this case D10, which might be a sales figure for Channel A). Searching through numeric or dates in your lookup column (the first column) requires the data to be sorted to avoid incorrect values being returned.

HLOOKUP is a horizontal lookup implementation of the vlookup formula. I find it’s rarely used but useful to keep in the back pocket for certain specific situations.

INDEX & MATCH are two formulas that combine together to create powerful, flexible lookup solutions. They are superior to vlookups by being more flexible and avoiding some of the pitfalls with vlookups (check out these articles here, here and here – they’re Excel based but still apply to Google Sheets). However, they are a little more complex to implement as they involve two nested formulas.

To create the same implementation as we had above with the vlookup, we could use this formula:

=INDEX(A1:D20,MATCH(F1,A1:A20,0),4)

Multi-condition lookup formula: Sometimes a simple lookup formula isn’t enough. For example, you may need to find a result based on two or more parameters (e.g. web traffic from a specific channel in a specific month). In this case, a multi-condition lookup formula can do the trick.

Say we have this table of Google Analytics data and need to retrieve the number of Search results in January 2015 (i.e. our answer is dependent on three criteria):

A B C D
1 ga:year ga:month ga:channel ga:sessions
2 2015 Jan Search 46,936
3 2015 Jan Email 922
4 2015 Jan Referral 4,973
5 2015 Feb Search 43,302
6

Let’s assume we have setup a staging table for our charts below this. To lookup the value we want (in this case Search for Jan 2015):

9
10 Year Month Search
11 2015 Jan
Formula?
12 2015 Feb
Formula?

we can use this formula in cell C11:

=ArrayFormula(INDEX($D$2:$D$9,MATCH($A11&$B11&C$10,$A$2:$A$9&$B$2:$B$9&$C$2:$C$9,0)))

which gives a result of 46,936.

Crazy huh! This formula was inspired by this post from Excel wizard Chandoo, and uses an index/match lookup wrapped in an array formula to compare multiple values across multiple columns in a data table. It concatenates the year, month and channel, to use as the lookup value, then looks for this concatenated value in the raw data across the year, month and channel columns. When it finds the right match it returns the corresponding result.

3. Apply logic with conditional formulas

COUNTIF is a formula which counts items in a range that match the specified criterion. It’s useful for doing things like counting non-blank cells in a range or counting the number of specific items in a range. The formula is:

=COUNTIF(range, criterion)

COUNTIFS is similar to the countif formula but returns a result based on multiple criteria. In other words, it counts the number of items in the first range that matches the first criteria AND also match a second criteria in a second range AND a third etc… The formula is slightly different to the basic countif formula, as follows:

=COUNTIFS(range1, criterion1, [range2, criterion2, ...])

SUMIF is the same idea as the countif, but returns a sum of the values. It’s possible to match criteria in one range, but sum values in a separate range, which is a really useful feature (e.g. imagine a table with names in column A and sales results in column B, then the sumif formula can sum the sales values for all occurrences of say “Ben” from the list of names). The formula for sumif is:

=SUMIF(range, criterion, [sum_range])

SUMIFS is the multi-criteria version of sumif, so it’s the same idea but the sum is calculated when you match multiple criteria in multiple ranges. Again, a very useful formula:

=SUMIFS(sum_range, range1, criterion1, [range2, criterion2, ...])

4. Automate your dates

Dashboards often have a date component to them, where a variable changes over time and merits being illustrated visually in the dashboard. There are various formulas/techniques available for automating this process.

The today formula, which gives the current date, will display the date the last time the spreadsheet was recalculated (for example, when you open it or make a change). The formula is:

=TODAY()

If you want to also have a current time element in your spreadsheet, then use the now formula, which returns the date and time the spreadsheet was last recalculated. The formula is:

=NOW()

Both the today and now functions can be set to update automatically, rather than just when the sheet is recalculated. Go to File > Spreadsheet Settings and then select “On change and every hour” or “On change and every minute”.

Be careful of inserting too many of these formulas in your spreadsheets as they are volatile functions, which means all that recalculating will harm your spreadsheet performance.

An example of using the today formula would be to display the current month in your dashboard, using the following text formula:

=TEXT(TODAY(),"MMMM")

For a more complex example, think of setting up start and end dates for a dashboard table, where I could enter formulas using the today function, set it to update automatically, and then base the other dates off that, using formulas.

The eomonth formula comes in handy here, returning the last day of a month which falls a specified number of months before or after another date.

For example, use the following formula to create the first day of the month prior to the current one:

=DATE(YEAR(TODAY()),MONTH(TODAY())-1,1)

I could then keep “rolling” the months back, by changing the “-1″ to “-2″ for two months prior, then “-3″, “-4″ all the way back to “-12″, to give the current month plus 12 preceding months in a table, which would automatically update as we move into each new month.

I could also get the first day of the current month but a year earlier, for example to compare current sales metrics against the same period last year, using the following formula:

=DATE(YEAR(TODAY())-1,MONTH(TODAY()),1)

See also:

> How do I get the first and last days of the current month?

> How do I get the first and last days of the prior month?

There are many possible variations from combining today, date, text and eomoth formulas, to get the correct periods you want in your Google Sheets dashboard and have them update automatically to stay current.

5. Add interactivity with data validation

Use data validation to add interactivity to your dashboards. You can create a nifty drop-down menu from which the user can select a parameter, e.g. a sales channel or specific time, and then change the data based on this choice, so any charts will update automatically. It’s a pretty simple technique but surprisingly powerful.

First, create a list of choices to present to the user, e.g. list of sales channels, and then using the Data > Validation feature on the highlighted list of values, create a user input menu for sales channels:

Data Validation setup
Data Validation setup

The user then has a drop down menu in your spreadsheet, from which he/she can select the desired parameter:

Data Validation menu
Data Validation menu

Data in the table which underpins a chart is changed based on the user’s choice from the drop-down menu above, by using one of the lookup formulas from step 2.

The following chart shows data validation in action, with the drop down menu in cell G5. Choose a name to change the chart. (feel free to make your own copy to edit): data validation example

Update: I created a new in-depth article and YouTube video on how to use data validation to create dynamic charts. Check it out:

6. Chart your data

Google has a whole suite of charts available to use with your data. Some of the most well known are the plain old bar/column chart, the much-maligned pie chart (for and against arguments. Personally, I think judicious use is ok), line charts and scatter plots. In addition though, Google Sheets has the ability to create map charts, interactive time series charts, gauges (can be useful if used judiciously) or combined “combo” charts, which allow you to combine different data series visualizations.

Examples

The humble bar chart can be tweaked into a stacked bar chart, which can be used to visualize two related metrics, for example how many sales have been made so far, versus how many are still required to hit the target.

Stacked bar chart
Stacked bar chart

An area chart can be used to show comparisons of data, as shown in this example of the cumulative sales during a digital flash sale, showing 2014 data against 2015 data:

Sales comparison area chart
Sales comparison area chart

More info on setting up charts in the official docs here.

7. Show trends with sparklines

Sparklines were first created by statistician and data visualization legend Edward Tufte. They’re small, simple charts without axes, which exist inside a single cell. They’re a wonderful, quick way for visually showing a result, without needing the complexity of a full-blown chart. They work well for datasets based on a timescale.

A sparkline looks like this:

Sparkline

The formula for sparklines in Google Sheets is:

=sparkline(data,[options])

where data refers to a range of values to plot the sparkline. The optional options argument is used to specify things like chart type (line, bar, column or winloss), color and other specific settings.

Update: I wrote a super detailed article about sparklines in Google Sheets. Check it out here.

8. Apply conditional formatting to show changes

Conditional formatting is formatting that changes according to some rule you set (e.g. when a number is greater than 0, or a date is before a certain date, or a text cell starts with a particular word). It’s a great tool to apply to tables in your Google Sheets dashboard where the data is changing.

For example, by changing the background color of table cells as the data changes, you can bring it to the attention of your dashboard user.

Consider the following sales table which you’ve created for your Google Sheets dashboard:

Google Sheets table

The formula in the final column compares the two metrics (2014 sales data and 2013 sales data) and then outputs a % change and indicator arrow. The formula is:

=IF(J9>I9, CONCATENATE(" +",TEXT((J9-I9)/I9,"0%"),REPT(" ",5),CHAR(9650)), IF(J9=I9,CONCATENATE("0%",REPT(" ",3),CHAR(9664)," ",CHAR(9658)),CONCATENATE(TEXT((J9-I9)/I9,"0%"),REPT(" ",5),CHAR(9660))))

There’s a lot going on here. We use two if formulas to check whether the 2014 value is greater than, equal to, or less than the 2013 value, and then create a different text output for each case. Considering the greater than case, I use concatenate to create a text string with “+”, the % value, a gap of five spaces (using the rept formula), and then a upward pointing black arrow (using the char formula and unicode character 9650more examples here).

Conditional formatting is accessed through:

Format > Conditional Formatting...

And I add the following three rules:

  • Text contains “+” for the greater than case
  • Text contains “-“ for the less than case
  • Text starts with “0%” for the case when the two metrics are equal

The final output looks like this (I’ve also added some regular formatting to the table):

Google Sheets table with conditional formatting

9. Format like a pro!

After all that effort to tease out the real stories hidden in your data, and make them accessible in charts and tables, it’s worth a little effort to spruce up the final version. Consider some of these ideas:

  • Change the color of charts in your Google Sheets dashboard to match your brand
  • Give all the tables a consistent format, e.g. light gray borders, a bold header row with white text and alternate gray/white shaded rows
  • Remove the gridlines. Find this option in the View menu: View > Gridlines
  • Add your logo to the top of the dashboard
  • Hide all working tabs except the dashboard tab (does not affect the functionality of the dashboard)
  • Use freeze panes, to lock specific rows or columns, so that if a user scrolls the header row(s) will be locked in place for example, and the title and user input options will always be visible. It’s found in the View menu: View > Freeze
  • View the dashboard in full screen mode

10. Share and publish your Google Sheets dashboard for the world to see

It’s quite likely you’ll want to share your dashboard with colleagues, clients and/or the world. There are a couple of ways of doing this.

Firstly, you can click the Share button in the top right corner of the screen, which opens up the sharing options pane:

Sharing Google Sheets

From here, you can enter email addresses to share directly with colleagues, or you can grab the sharing url and email that to people you want to share with, or paste into social media channels.

You have control over the access rights and whether recipients of the link can view, comment on or edit the dashboard. More information on the sharing settings in Google sheets here.

Secondly, you can publish your Google Sheets dashboard as a web page, or embed it as a component in another page, by clicking on:

File > Publish to the web...

which brings up this pane of options:

Google Sheets Publish to web

Publishing this way makes the dashboard visible to the public. For example, here is the Color Picker Form dashboard example from section 1 of this post, published online as a web app:

Google Sheets dashboard published as web page

Thoughts or comments? Do you have a favorite technique or formula for dashboards? Leave your ideas below!

24 thoughts on “10 techniques for building a Google Sheets dashboard”

  1. Hello Ben,

    I am so glad to have found this article on web. this is so helpful me to groom myself. Being novice business analyst at a startup, i was struggling to make dashboards on excel. After 2 months of self learning i manage to create dashboards with slicers on Win excel 2013, which sadly could not run on managers Apple PC (because of absence of slicers features on Apple PC),

    I have to now transform every thing on a common platform like google sheets. was worried about how do i start with limited time in hand.

    Your article will definitely help me with a great start. but i am still wondering for other ms excel features if present on google sheets like dependent drop box. well i will have to dive in to learn more.

    Thanks for your help,
    Reynold.

  2. Ben, great article with some great ideas. Thank you! My question is regarding SPARKLINE and if it’s possible to use an array in conjunction with it (I am just getting baptized in all the greatness of Sheets and don’t really know the lingo). My intended outcome is to have a SPARKLINE column chart at the end of each row of data (I imported my data using IMPORTRANGE from a Form Response Sheet and it will frequently update). Is there a way to have SPARKLINE applied to each row of data that is imported or would I have to manually set that up?

    1. Thanks John. One way to do this would be to simply have the sparkline formulas all set up in advance, in the column next to your imported data.

      For example, say you were importing your data into columns A through D with headings in row 1, then I would add the following formula into cell E2 (i.e. the column at the end of your imported data):

      =if(isblank(D2),””,sparkline(data,[options]))

      Then simply copy it down, way past your current last row. It’ll be blank until you import data and then it’ll create a sparkline for you. Basically it tests whether the cell is blank and creates a sparkline if it finds a value.

    1. Hey Neeti,

      This is a rather general question so it’s difficult to give specific advice, but he’s a few tips that might help:

      You’ll want to have sales as your vertical y-axis and time series as your horizontal x-axis in your chart. So you’ll need this data in two columns, then you can select it and insert a column chart.

      If you want to group the data into months first, then use this formula: =month() to extract the month for each date in your dataset, then create a pivot table of your data with Months as row headers and sum your sales values (this will aggregate the data), before creating a column chart as before.

      Some other formulas that might help:

      To get today’s date use the formula =today()

      Then, assuming today’s date is in cell A1, use this formula to get the same date but one year ago:

      =date(year(A1)-1,month(A1),day(A1))

      You can extract your sales dataset based off today and this date one year ago.

      Hope that helps!

      Ben

  3. Hi Ben,

    This is really great! congrats!

    I’m looking to move away from Microsoft PowerPivot, but I cannot get the great functionality slicers provide. I can see how your data validation is very close to it, but I don’t think it is slicing data to the level I need. I use that to build segments of users.

    Do you have any suggestion on how to better achieve this?
    Hopefully with these tips I can finally get rid of my windows machine and go back to super convientent for all web work macbook.

    Thanks

  4. Awesome Ben!! Beautiful work. Thank you for the information, very useful and very clear. I have only one Q’? Do you think is possible to create a very simple tracking tool, could be “embedded” or a “public HTML”, that uses the Google Sheet as a database and makes possible to give someone information based on a specific number they search for? Like a search query. Something similar to Fedex or UPS when you “track” a shipment. You search for a number they’ve given you, and with this number you can see the “status” of a process. Is something I think is possible, but just don’t know how to easily make it!!! thanks

  5. Hi Ben,

    Really appreciate your work here! It would be very great if you take some time to look at our problem belew and maybe provide us some guidance.

    We have already used dashboards in Google Sheets for a year in our startup, but when the data got in to more than 100,000 rows we struggled to work with the sheets.

    To be specific, we import raw data into a separate spreadsheets (we call this function spreadsheets) where we perform lookup and calculation, then export them to new ones for reporting. The problem is that now the function spreadsheets get too large and take a long time to load, sometimes they crash. I had some pop-ups in my head that told us to migrate our data into an ‘actual’ database (we prefer open-source ones like MySQL) for scalable practices. However, I have two unanswered questions:
    1. How can we still build dashboards in Google Sheets with our new MySQL database without importing data (because if we import then we solve nearly no problems here). Our analytics team has been familiar with Google Sheets.
    2. If we shouldn’t create dashboards with Google Sheets when our data has grown big, what are our alternatives that are free and ‘open-source’-like. We prefer to take time over money.

    I know that I am asking quite much, but I myself struggle with the problem for nearly a month! Thanks very much and really sorry for any inconveniences.

    1. Hey Quy,

      Yes, it definitely sounds like you’ve reached the point of needing a database!

      You’ll want to migrate all of your data into the MySQL database and then connect your Google Sheet to the database. You can write SQL statements to then retrieve only the data you want to show in your Google Sheets or dashboards, which should solve the performance issues.

      However, connecting Sheets to MySQL is not a trivial exercise and involves some coding in Apps Script. This seems to be the best resource I’ve found: http://www.mousewhisperer.co.uk/drivebunny/connecting-to-mysql-databases-using-apps-script/

      (Alternatively, you could use a service like Zapier, but then you’ll be paying for something which you want to avoid.)

      In terms of open source dashboard tools for MySQL direct, there are some tools out there of varying degrees of skill level. I haven’t used any that connect with MySQL though, so don’t have any specific recommendations there. If you don’t mind your dashboards living in the open on Tableau servers, then Tableau Public is free and as powerful a dashboard tool as they come.

      Hope that helps!

      Cheers,
      Ben

      1. Thanks Ben!

        Actually I have spent my recent two weeks writing some Google Apps Script codes to push and pull data between MySQL and Google Sheets. Basically they work, but the best I can do is to, once a day, trigger the raw data spreadsheets to push to as well as make the function spreadsheet pull from MySQL.

        However, what we put emphasis on from dashboards is real-time capability, and my solution seems to not capture that. Moreover, we already made use of the Google Sheets built-in Query and Importrange functions to build function spreadsheets, so whatever data in those sheets are exactly what needed for lookup and calculation. Being able to pull those data from MySQL does help with some other issues but not really for building dashboards on Google Sheets…

        I’m a fan of Tableau, but to my knowledge Tableau Public does not allow for connection to online database. Our team is discussing on whether they should just import less, it seems like the most possible answer right now …

        Again, many thanks for your reply, it helps me a lot and I really appreciate it! Also sorry because I’m not really good at communication in English.

        Best,
        Quy 😀

        1. Quy – you’re right! It’s been a while since I’ve used Tableau Public and I forgot that the MySQL connector isn’t available on the public version. Can you not set your trigger to run once an hour? Would that be real-time enough?

          1. Thanks for your suggestion, Ben. We have people work in the raw data sheets all day, so a script that runs once every hour would interrupt them for a while, and may cause disorder I suppose. That’s why I originally intend to trigger the script only at midnight.

            Maybe it’s time to seriously consider migrating those processes into some modern kind of databases with tailored user input form… Ben, do you think that the only choice I have left is to ask the tech-team to build something like that?

            1. Well, it sounds like it’s worth investigating that route.

              Maybe you could import the data into one master sheet hourly, and then have your team work on different sheets using the IMPORTRANGE formula. Maybe that would reduce disruption although I haven’t tried this particular scenario myself.

              Cheers,
              Ben

  6. Hi Ben – Question: When I publish a sheet to the web and embed it into a webpage on WIX I can’t seem to figure out how to format the sheet so the borders won’t show. I see the name of my sheet at the top and published by Google Sheets – Report Abuse – Updated automatically every 5 minutes at the bottom. Is there any way to completely eliminate those? Thanks.

    Your course looks great by the way and I love your tips. Thank you!

    1. Hi Ed,

      Try these red settings in your iframe code:

      <iframe src="https://docs.google.com/spreadsheets/d/************************************************/pubhtml?gid=471022821&single=true&widget=false&headers=false&chrome=false" height="280" width="800"></iframe>

      More info here in the docs here: https://support.google.com/docs/answer/37579#embed

      If that doesn’t work, then I’m not sure there’s anything else you can do, but you could try the forum: https://productforums.google.com/forum/#!topicsearchin/docs/category$3Aspreadsheets

      Hope that helps!

  7. I have a dashboard with a lot of charts. I really like the ease of use of Google Spreadsheets. However, my charts seem to move around and not stay put. I want them to be in nice rows and columns and stay that way.

    Have you found any way to force the chart to stay inside of a cell? So I can make all the charts the same size and maintain clean lines?

    1. Hey Dan, this is a good question. I sometimes find my charts creep around a little (never by much) but I don’t know of anyway to “lock” them. It’s always been very minor so I’ve just lived with it.

      You can use sparklines to create mini charts inside a cell, and you could always make the cell bigger or merge lots of cells together to make a bigger chart if you want. I use this tactic a lot with dashboards.

      Cheers,
      Ben

Leave a Reply to Albert Malagarriga Cancel reply

Your email address will not be published. Required fields are marked *